Cảm biến độ ẩm DHT11

// Đọc cảm biến DHT11 bằng Arduino Uno - hiển thị qua Serial Monitor (9600 baud)
#include <DHT.h>

#define DHTPIN  2        // Chân DATA nối D2
#define DHTTYPE DHT11

DHT dht(DHTPIN, DHTTYPE);

void setup() {
  Serial.begin(9600);
  dht.begin();
  Serial.println("DHT11 - MShop");
}

void loop() {
  delay(2000);                         // DHT11 cần >= 1 giây giữa 2 lần đọc

  float h = dht.readHumidity();        // Độ ẩm %
  float t = dht.readTemperature();     // Nhiệt độ °C

  if (isnan(h) || isnan(t)) {
    Serial.println("Loi doc cam bien DHT11!");
    return;
  }

  float hic = dht.computeHeatIndex(t, h, false);  // Chỉ số cảm nhiệt

  Serial.print("Do am: ");
  Serial.print(h);
  Serial.print(" %  |  Nhiet do: ");
  Serial.print(t);
  Serial.print(" *C  |  Cam nhan: ");
  Serial.print(hic);
  Serial.println(" *C");
}

// ESP32 + DHT11: tự động bật quạt khi nhiệt độ cao
#include <DHT.h>

#define DHTPIN    4
#define DHTTYPE   DHT11
#define RELAY_PIN 26

const float NGUONG_BAT = 32.0;   // °C
const float NGUONG_TAT = 30.0;   // °C

DHT dht(DHTPIN, DHTTYPE);
bool quatDangBat = false;

void setup() {
  Serial.begin(115200);
  pinMode(RELAY_PIN, OUTPUT);
  digitalWrite(RELAY_PIN, LOW);
  dht.begin();
}

void loop() {
  float t = dht.readTemperature();
  float h = dht.readHumidity();

  if (!isnan(t) && !isnan(h)) {
    if (!quatDangBat && t >= NGUONG_BAT) quatDangBat = true;
    if (quatDangBat && t <= NGUONG_TAT)  quatDangBat = false;
    digitalWrite(RELAY_PIN, quatDangBat ? HIGH : LOW);

    Serial.printf("T = %.1f *C, H = %.0f %% -> Quat: %s\n",
                  t, h, quatDangBat ? "BAT" : "TAT");
  }
  delay(2000);
}