Cảm biến góc GY-521 MPU6050

// MPU6050 - đọc gia tốc, gyro, nhiệt độ và tính góc Roll/Pitch
#include <Wire.h>

const uint8_t MPU_ADDR = 0x68;

int16_t ax, ay, az, nhietRaw, gx, gy, gz;

void setup() {
  Serial.begin(115200);
  Wire.begin();

  Wire.beginTransmission(MPU_ADDR);
  Wire.write(0x6B);          // PWR_MGMT_1
  Wire.write(0x00);          // Đánh thức MPU6050
  Wire.endTransmission(true);
}

void docMPU() {
  Wire.beginTransmission(MPU_ADDR);
  Wire.write(0x3B);          // Thanh ghi bắt đầu ACCEL_XOUT_H
  Wire.endTransmission(false);
  Wire.requestFrom(MPU_ADDR, (uint8_t)14);

  ax = Wire.read() << 8 | Wire.read();
  ay = Wire.read() << 8 | Wire.read();
  az = Wire.read() << 8 | Wire.read();
  nhietRaw = Wire.read() << 8 | Wire.read();
  gx = Wire.read() << 8 | Wire.read();
  gy = Wire.read() << 8 | Wire.read();
  gz = Wire.read() << 8 | Wire.read();
}

void loop() {
  docMPU();

  // Thang mặc định: ±2g (16384 LSB/g), ±250 °/s (131 LSB/°/s)
  float Ax = ax / 16384.0, Ay = ay / 16384.0, Az = az / 16384.0;
  float Gx = gx / 131.0,   Gy = gy / 131.0,   Gz = gz / 131.0;
  float nhietDo = nhietRaw / 340.0 + 36.53;

  float roll  = atan2(Ay, Az) * 180.0 / PI;
  float pitch = atan2(-Ax, sqrt(Ay * Ay + Az * Az)) * 180.0 / PI;

  Serial.print("Acc(g): ");   Serial.print(Ax, 2); Serial.print(", ");
  Serial.print(Ay, 2);        Serial.print(", ");  Serial.print(Az, 2);
  Serial.print(" | Gyro(dps): "); Serial.print(Gx, 1); Serial.print(", ");
  Serial.print(Gy, 1);        Serial.print(", ");  Serial.print(Gz, 1);
  Serial.print(" | Roll: ");  Serial.print(roll, 1);
  Serial.print(" Pitch: ");   Serial.print(pitch, 1);
  Serial.print(" | T: ");     Serial.println(nhietDo, 1);

  delay(200);
}

#include <Adafruit_MPU6050.h>
#include <Adafruit_Sensor.h>
#include <Wire.h>

Adafruit_MPU6050 mpu;

void setup() {
  Serial.begin(115200);
  Wire.begin(21, 22);                    // SDA, SCL

  if (!mpu.begin()) {
    Serial.println("Khong tim thay MPU6050, kiem tra day!");
    while (1) delay(10);
  }
  mpu.setAccelerometerRange(MPU6050_RANGE_4_G);
  mpu.setGyroRange(MPU6050_RANGE_500_DEG);
  mpu.setFilterBandwidth(MPU6050_BAND_21_HZ);
}

void loop() {
  sensors_event_t a, g, temp;
  mpu.getEvent(&a, &g, &temp);

  Serial.printf("Acc: %.2f %.2f %.2f m/s2 | Gyro: %.2f %.2f %.2f rad/s | %.1f C\n",
                a.acceleration.x, a.acceleration.y, a.acceleration.z,
                g.gyro.x, g.gyro.y, g.gyro.z, temp.temperature);
  delay(200);
}